Admin

name	type	size	perms	modified	actions
[parent directory]
BlackBox.pm	file	86,643 B	0644	2023-05-11 19:13:11	edit
Checker.pm	file	5,416 B	0644	2023-05-11 19:13:11	edit
Debug.pm	file	4,596 B	0644	2023-05-11 19:13:11	edit
DumpAsText.pm	file	4,039 B	0644	2023-05-11 19:13:11	edit
DumpAsXML.pm	file	4,569 B	0644	2023-05-11 19:13:11	edit
HTML.pm	file	34,621 B	0644	2023-05-11 19:13:11	edit
HTMLBatch.pm	file	40,514 B	0644	2023-05-11 19:13:11	edit
HTMLLegacy.pm	file	2,731 B	0644	2023-05-11 19:09:14	edit
JustPod.pm	file	9,632 B	0644	2023-05-11 19:09:14	edit
LinkSection.pm	file	4,282 B	0644	2023-05-11 19:13:11	edit
Methody.pm	file	3,555 B	0644	2023-05-11 19:13:11	edit
Progress.pm	file	2,419 B	0644	2023-05-11 19:13:11	edit
PullParser.pm	file	25,663 B	0644	2023-05-11 19:13:11	edit
PullParserEndToken.pm	file	2,868 B	0644	2023-05-11 19:13:11	edit
PullParserStartToken.pm	file	4,130 B	0644	2023-05-11 19:13:11	edit
PullParserTextToken.pm	file	3,347 B	0644	2023-05-11 19:13:11	edit
PullParserToken.pm	file	4,016 B	0644	2023-05-11 19:13:11	edit
RTF.pm	file	23,460 B	0644	2023-05-11 19:13:11	edit
Search.pm	file	35,731 B	0644	2023-05-11 19:13:11	edit
SimpleTree.pm	file	4,592 B	0644	2023-05-11 19:13:11	edit
Subclassing.pod	file	34,079 B	0644	2023-05-11 19:09:14	edit
Text.pm	file	5,093 B	0644	2023-05-11 19:13:11	edit
TextContent.pm	file	2,499 B	0644	2023-05-11 19:13:11	edit
TiedOutFH.pm	file	2,735 B	0644	2023-05-11 19:13:11	edit
Transcode.pm	file	710 B	0644	2023-05-11 19:13:11	edit
TranscodeDumb.pm	file	2,605 B	0644	2023-05-11 19:13:11	edit
TranscodeSmart.pm	file	693 B	0644	2023-05-11 19:13:11	edit
XHTML.pm	file	27,806 B	0644	2023-05-11 19:13:11	edit
XMLOutStream.pm	file	4,659 B	0644	2023-05-11 19:13:11	edit

editing: SimpleTree.pm

package Pod::Simple::SimpleTree;
use strict;
use warnings;
use Carp ();
use Pod::Simple ();
our $VERSION = '3.45';
BEGIN {
  our @ISA = ('Pod::Simple');
  *DEBUG = \&Pod::Simple::DEBUG unless defined &DEBUG;
}

__PACKAGE__->_accessorize(
  'root',   # root of the tree
);

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

sub _handle_element_start { # self, tagname, attrhash
  DEBUG > 2 and print STDERR "Handling $_[1] start-event\n";
  my $x = [$_[1], $_[2]];
  if($_[0]{'_currpos'}) {
    push    @{ $_[0]{'_currpos'}[0] }, $x; # insert in parent's child-list
    unshift @{ $_[0]{'_currpos'} },    $x; # prefix to stack
  } else {
    DEBUG and print STDERR " And oo, it gets to be root!\n";
    $_[0]{'_currpos'} = [   $_[0]{'root'} = $x   ];
      # first event!  set to stack, and set as root.
  }
  DEBUG > 3 and print STDERR "Stack is now: ",
    join(">", map $_->[0], @{$_[0]{'_currpos'}}), "\n";
  return;
}

sub _handle_element_end { # self, tagname
  DEBUG > 2 and print STDERR "Handling $_[1] end-event\n";
  shift @{$_[0]{'_currpos'}};
  DEBUG > 3 and print STDERR "Stack is now: ",
    join(">", map $_->[0], @{$_[0]{'_currpos'}}), "\n";
  return;
}

sub _handle_text { # self, text
  DEBUG > 2 and print STDERR "Handling $_[1] text-event\n";
  push @{ $_[0]{'_currpos'}[0] }, $_[1];
  return;
}

# A bit of evil from the black box...  please avert your eyes, kind souls.
sub _traverse_treelet_bit {
  DEBUG > 2 and print STDERR "Handling $_[1] paragraph event\n";
  my $self = shift;
  push @{ $self->{'_currpos'}[0] }, [@_];
  return;
}
#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1;
__END__

=head1 NAME

Pod::Simple::SimpleTree -- parse Pod into a simple parse tree

=head1 SYNOPSIS

% cat ptest.pod

=head1 PIE

I like B<pie>!

% perl -MPod::Simple::SimpleTree -MData::Dumper -e \
     "print Dumper(Pod::Simple::SimpleTree->new->parse_file(shift)->root)" \
     ptest.pod

$VAR1 = [
            'Document',
            { 'start_line' => 1 },
            [
              'head1',
              { 'start_line' => 1 },
              'PIE'
            ],
            [
              'Para',
              { 'start_line' => 3 },
              'I like ',
              [
                'B',
                {},
                'pie'
              ],
              '!'
            ]
          ];

=head1 DESCRIPTION

This class is of interest to people writing a Pod processor/formatter.

This class takes Pod and parses it, returning a parse tree made just
of arrayrefs, and hashrefs, and strings.

This is a subclass of L<Pod::Simple> and inherits all its methods.

This class is inspired by XML::Parser's "Tree" parsing-style, although
it doesn't use exactly the same LoL format.

=head1 METHODS

At the end of the parse, call C<< $parser->root >> to get the
tree's top node.

=head1 Tree Contents

Every element node in the parse tree is represented by an arrayref of
the form: C<[ I<elementname>, \%attributes, I<...subnodes...> ]>.
See the example tree dump in the Synopsis, above.

Every text node in the tree is represented by a simple (non-ref)
string scalar.  So you can test C<ref($node)> to see whether you have
an element node or just a text node.

The top node in the tree is C<[ 'Document', \%attributes,
I<...subnodes...> ]>

=head1 SEE ALSO

L<Pod::Simple>

L<perllol>

L<The "Tree" subsubsection in XML::Parser|XML::Parser/"Tree">

=head1 SUPPORT

Questions or discussion about POD and Pod::Simple should be sent to the
pod-people@perl.org mail list. Send an empty email to
pod-people-subscribe@perl.org to subscribe.

This module is managed in an open GitHub repository,
L<https://github.com/perl-pod/pod-simple/>. Feel free to fork and contribute, or
to clone L<https://github.com/perl-pod/pod-simple.git> and send patches!

Patches against Pod::Simple are welcome. Please send bug reports to
<bug-pod-simple@rt.cpan.org>.

=head1 COPYRIGHT AND DISCLAIMERS

This library is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.

This program is distributed in the hope that it will be useful, but
without any warranty; without even the implied warranty of
merchantability or fitness for a particular purpose.

=head1 AUTHOR

Pod::Simple was created by Sean M. Burke <sburke@cpan.org>.
But don't bother him, he's retired.

Pod::Simple is maintained by:

=over

=item * Allison Randal C<allison@perl.org>

=item * Hans Dieter Pearcey C<hdp@cpan.org>

=item * David E. Wheeler C<dwheeler@cpan.org>

=back

=cut

cancel