Admin

name	type	size	perms	modified	actions
[parent directory]
internal/	dir	-	0755	2026-08-19 08:36:05
amversion.m4	file	1,617 B	0644	2021-10-04 03:06:47	edit
ar-lib.m4	file	2,066 B	0644	2021-07-12 02:41:13	edit
as.m4	file	767 B	0644	2021-07-12 02:41:13	edit
auxdir.m4	file	2,407 B	0644	2021-07-12 02:41:13	edit
cond-if.m4	file	1,030 B	0644	2021-07-12 02:41:13	edit
cond.m4	file	1,036 B	0644	2021-07-12 02:41:13	edit
depend.m4	file	7,281 B	0644	2021-07-12 02:41:13	edit
depout.m4	file	2,772 B	0644	2021-07-12 02:41:13	edit
dmalloc.m4	file	906 B	0644	2021-07-12 02:41:13	edit
extra-recurs.m4	file	738 B	0644	2021-07-12 02:41:13	edit
gcj.m4	file	649 B	0644	2021-07-12 02:41:13	edit
init.m4	file	8,426 B	0644	2021-09-20 00:53:14	edit
install-sh.m4	file	681 B	0644	2021-07-12 02:41:13	edit
lead-dot.m4	file	641 B	0644	2021-07-12 02:41:13	edit
lex.m4	file	689 B	0644	2021-07-12 02:41:13	edit
lispdir.m4	file	2,152 B	0644	2021-07-12 02:41:13	edit
maintainer.m4	file	1,656 B	0644	2021-07-12 02:41:13	edit
make.m4	file	1,434 B	0644	2021-07-12 02:41:13	edit
missing.m4	file	1,052 B	0644	2021-07-12 02:41:13	edit
mkdirp.m4	file	1,349 B	0644	2021-07-12 02:41:13	edit
obsolete.m4	file	1,008 B	0644	2021-07-12 02:41:13	edit
options.m4	file	1,090 B	0644	2021-07-12 02:41:13	edit
prog-cc-c-o.m4	file	1,691 B	0644	2021-07-12 02:41:13	edit
python.m4	file	13,869 B	0644	2021-10-04 02:51:12	edit
runlog.m4	file	718 B	0644	2021-07-12 02:41:13	edit
sanity.m4	file	2,646 B	0644	2021-07-12 02:41:13	edit
silent.m4	file	1,911 B	0644	2021-07-12 02:41:13	edit
strip.m4	file	1,392 B	0644	2021-07-12 02:41:13	edit
substnot.m4	file	675 B	0644	2021-07-12 02:41:13	edit
tar.m4	file	4,471 B	0644	2021-07-12 02:41:13	edit
upc.m4	file	836 B	0644	2021-07-12 02:41:13	edit
vala.m4	file	1,884 B	0644	2021-07-12 02:41:13	edit

editing: sanity.m4

# Check to make sure that the build environment is sane.    -*- Autoconf -*-

# Copyright (C) 1996-2021 Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# AM_SANITY_CHECK
# ---------------
AC_DEFUN([AM_SANITY_CHECK],
[AC_MSG_CHECKING([whether build environment is sane])
# Reject unsafe characters in $srcdir or the absolute working directory
# name.  Accept space and tab only in the latter.
am_lf='
'
case `pwd` in
  *[[\\\"\#\$\&\'\`$am_lf]]*)
    AC_MSG_ERROR([unsafe absolute working directory name]);;
esac
case $srcdir in
  *[[\\\"\#\$\&\'\`$am_lf\ \	]]*)
    AC_MSG_ERROR([unsafe srcdir value: '$srcdir']);;
esac

# Do 'set' in a subshell so we don't clobber the current shell's
# arguments.  Must try -L first in case configure is actually a
# symlink; some systems play weird games with the mod time of symlinks
# (eg FreeBSD returns the mod time of the symlink's containing
# directory).
if (
   am_has_slept=no
   for am_try in 1 2; do
     echo "timestamp, slept: $am_has_slept" > conftest.file
     set X `ls -Lt "$srcdir/configure" conftest.file 2> /dev/null`
     if test "$[*]" = "X"; then
	# -L didn't work.
	set X `ls -t "$srcdir/configure" conftest.file`
     fi
     if test "$[*]" != "X $srcdir/configure conftest.file" \
	&& test "$[*]" != "X conftest.file $srcdir/configure"; then

# If neither matched, then we have a broken ls.  This can happen
	# if, for instance, CONFIG_SHELL is bash and it inherits a
	# broken ls alias from the environment.  This has actually
	# happened.  Such a system could not be considered "sane".
	AC_MSG_ERROR([ls -t appears to fail.  Make sure there is not a broken
  alias in your environment])
     fi
     if test "$[2]" = conftest.file || test $am_try -eq 2; then
       break
     fi
     # Just in case.
     sleep 1
     am_has_slept=yes
   done
   test "$[2]" = conftest.file
   )
then
   # Ok.
   :
else
   AC_MSG_ERROR([newly created file is older than distributed files!
Check your system clock])
fi
AC_MSG_RESULT([yes])
# If we didn't sleep, we still need to ensure time stamps of config.status and
# generated files are strictly newer.
am_sleep_pid=
if grep 'slept: no' conftest.file >/dev/null 2>&1; then
  ( sleep 1 ) &
  am_sleep_pid=$!
fi
AC_CONFIG_COMMANDS_PRE(
  [AC_MSG_CHECKING([that generated files are newer than configure])
   if test -n "$am_sleep_pid"; then
     # Hide warnings about reused PIDs.
     wait $am_sleep_pid 2>/dev/null
   fi
   AC_MSG_RESULT([done])])
rm -f conftest.file
])

cancel