Admin

name	type	size	perms	modified	actions
[parent directory]
bison-i18n.m4	file	1,939 B	0644	2021-06-23 04:48:48	edit
build-to-host.m4	file	3,235 B	0644	2024-02-21 10:43:47	edit
dovecot-pigeonhole.m4	file	1,895 B	0644	2026-07-13 00:00:00	edit
freetype2.m4	file	6,331 B	0644	2023-02-27 05:39:44	edit
gettext.m4	file	15,479 B	0644	2023-11-17 11:46:33	edit
glib-2.0.m4	file	8,371 B	0644	2024-07-08 14:03:15	edit
glib-gettext.m4	file	15,744 B	0644	2024-07-08 14:03:15	edit
gpg-error.m4	file	9,117 B	0644	2024-06-19 07:02:51	edit
gpgrt.m4	file	4,085 B	0644	2018-11-15 18:28:20	edit
gsettings.m4	file	3,589 B	0644	2024-07-08 14:03:15	edit
host-cpu-c-abi.m4	file	17,132 B	0644	2024-02-21 10:43:41	edit
iconv.m4	file	9,681 B	0644	2024-02-21 14:16:04	edit
intlmacosx.m4	file	3,504 B	0644	2024-02-21 14:16:04	edit
lib-ld.m4	file	5,384 B	0644	2024-02-21 10:43:41	edit
lib-link.m4	file	35,740 B	0644	2024-02-21 10:43:41	edit
lib-prefix.m4	file	12,502 B	0644	2024-02-21 10:43:41	edit
libtool.m4	file	307,188 B	0644	2024-10-29 00:00:00	edit
libxml.m4	file	461 B	0644	2023-12-13 14:51:48	edit
libxslt.m4	file	8,016 B	0644	2023-02-26 13:08:58	edit
ltargz.m4	file	2,670 B	0644	2022-03-17 02:43:39	edit
ltdl.m4	file	30,061 B	0644	2022-03-17 02:43:39	edit
ltoptions.m4	file	14,525 B	0644	2022-03-17 02:43:39	edit
ltsugar.m4	file	4,395 B	0644	2022-03-17 02:43:39	edit
ltversion.m4	file	714 B	0644	2022-03-17 02:45:14	edit
lt~obsolete.m4	file	6,151 B	0644	2022-03-17 02:43:39	edit
mysql.m4	file	4,221 B	0644	2010-07-04 00:00:00	edit
nls.m4	file	1,234 B	0644	2024-02-21 14:16:04	edit
pkg.m4	file	12,735 B	0644	2023-01-22 10:57:54	edit
po.m4	file	19,019 B	0644	2024-02-21 14:16:04	edit
progtest.m4	file	3,089 B	0644	2024-02-21 14:16:04	edit

editing: build-to-host.m4

# build-to-host.m4 serial 3
dnl Copyright (C) 2023-2024 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

dnl Written by Bruno Haible.

dnl When the build environment ($build_os) is different from the target runtime
dnl environment ($host_os), file names may need to be converted from the build
dnl environment syntax to the target runtime environment syntax. This is
dnl because the Makefiles are executed (mostly) by build environment tools and
dnl therefore expect file names in build environment syntax, whereas the runtime
dnl expects file names in target runtime environment syntax.
dnl
dnl For example, if $build_os = cygwin and $host_os = mingw32, filenames need
dnl be converted from Cygwin syntax to native Windows syntax:
dnl   /cygdrive/c/foo/bar -> C:\foo\bar
dnl   /usr/local/share    -> C:\cygwin64\usr\local\share
dnl
dnl gl_BUILD_TO_HOST([somedir])
dnl This macro takes as input an AC_SUBSTed variable 'somedir', which must
dnl already have its final value assigned, and produces two additional
dnl AC_SUBSTed variables 'somedir_c' and 'somedir_c_make', that designate the
dnl same file name value, just in different syntax:
dnl   - somedir_c       is the file name in target runtime environment syntax,
dnl                     as a C string (starting and ending with a double-quote,
dnl                     and with escaped backslashes and double-quotes in
dnl                     between).
dnl   - somedir_c_make  is the same thing, escaped for use in a Makefile.

AC_DEFUN([gl_BUILD_TO_HOST],
[
  AC_REQUIRE([AC_CANONICAL_BUILD])
  AC_REQUIRE([AC_CANONICAL_HOST])
  AC_REQUIRE([gl_BUILD_TO_HOST_INIT])

dnl Define somedir_c.
  gl_final_[$1]="$[$1]"
  dnl Translate it from build syntax to host syntax.
  case "$build_os" in
    cygwin*)
      case "$host_os" in
        mingw* | windows*)
          gl_final_[$1]=`cygpath -w "$gl_final_[$1]"` ;;
      esac
      ;;
  esac
  dnl Convert it to C string syntax.
  [$1]_c=`printf '%s\n' "$gl_final_[$1]" | sed -e "$gl_sed_double_backslashes" -e "$gl_sed_escape_doublequotes" | tr -d "$gl_tr_cr"`
  [$1]_c='"'"$[$1]_c"'"'
  AC_SUBST([$1_c])

dnl Define somedir_c_make.
  [$1]_c_make=`printf '%s\n' "$[$1]_c" | sed -e "$gl_sed_escape_for_make_1" -e "$gl_sed_escape_for_make_2" | tr -d "$gl_tr_cr"`
  dnl Use the substituted somedir variable, when possible, so that the user
  dnl may adjust somedir a posteriori when there are no special characters.
  if test "$[$1]_c_make" = '\"'"${gl_final_[$1]}"'\"'; then
    [$1]_c_make='\"$([$1])\"'
  fi
  AC_SUBST([$1_c_make])
])

dnl Some initializations for gl_BUILD_TO_HOST.
AC_DEFUN([gl_BUILD_TO_HOST_INIT],
[
  gl_sed_double_backslashes='s/\\/\\\\/g'
  gl_sed_escape_doublequotes='s/"/\\"/g'
changequote(,)dnl
  gl_sed_escape_for_make_1="s,\$[ \"&'();<>\\\\\`|]\$,\\\\\\1,g"
changequote([,])dnl
  gl_sed_escape_for_make_2='s,\$,\\$$,g'
  dnl Find out how to remove carriage returns from output. Solaris /usr/ucb/tr
  dnl does not understand '\r'.
  case `echo r | tr -d '\r'` in
    '') gl_tr_cr='\015' ;;
    *)  gl_tr_cr='\r' ;;
  esac
])

cancel